wissel.net :: Reinstalling Windows stuff

Version	Support end
5.0
6.0
6.5
7.0

From time to time it is healthy to reinstall Windows XP. At IBM I have the luxury to use the cloning center or the cloning CD. Boot it, log in and off you go. It installs Windows including the standard IBM applications like VPN, Lotus Notes and some standard internal stuff (It used to install MS Office, but no longer in the 2008 built). So far so good. But we all know that there is an army of little helpers and tweaks that make it your copy of Windows.
To ease my pain installing all of them I keep a directory reinstall on an external medium (DVD, Memory Stick, Harddisk, NAS, make your pick) where I keep all the install files and extra stuff. To automate the process I use two cmd files:
reinstall.cmd
installthis.cmd
All regular installers sit in the root of the install directory. There are a few mandatory sub directories. I have phase2 for installers that depend on software I install in the first round. Techsmith is the directory for the Techsmith SnagIt (highly recommended) tool and AuxiliaryFiles keeps miscelanous stuff. When a new version of an application comes out or I install a new tool, I just add the installer to this directory and in the next full makeover I won't forget it. Let's have a look at the cmd files.

reinstall.cmd

@echo off
cls
echo.
echo.
echo.  This will reinstall all extra software on a newly
echo.  (re)installed Thinkpad. The source directory needs
echo.  to be maintained properly
echo.
echo.
start notepad keys.txt
REM ---- All exe and msi files
for %%x in (*.exe *.msi) do call installthis.cmd %%x

REM Rational Installer (sits in its own directory)
:rational
SET continue=y
echo.
echo.
echo.  Install Rational Install Manager ?
echo.
echo.
SET /P continue=Install? [%continue%]
if not x%continue%x==xyx GOTO putty
echo.
echo.
echo. Rational Install Manager
CD Rational
install.exe
CD ..

REM Putty (Just copy no installer)
:putty
SET continue=y
echo.
echo.
echo.  Install Putty ?
echo.
echo.
SET /P continue=Install? [%continue%]
if not x%continue%x==xyx GOTO fonts
echo.
echo.
echo. Installing Putty
MD "%ProgramFiles%\Putty"
COPY AuxiliaryFiles\PUtty.exe "%ProgramFiles%\Putty\Putty.exe"

REM ---- Fonts
:fonts
SET continue=y
echo.
echo.
echo.  Install Extra fonts?
echo.
echo.
SET /P continue=Install? [%continue%]
if not x%continue%x==xyx GOTO snag
echo.
echo.
echo. Installing fonts
cd fonts
for %%x in (*.*) do if not exist "%windir%\FONTS\%%x" copy "%%x" %windir%\FONTS
cd ..

REM ---- Snagit Files
:snag
SET continue=y
echo.
echo.
echo.  Install Snagit stamps
echo.
echo.
SET /P continue=Install? [%continue%]
if not x%continue%x==xyx GOTO misc
echo.
echo.
echo. Installing Snagit stamps
FOR %%x in (Techsmith\*.exe) do %%x /s
FOR %%x in (Techsmith\*.msi) do %%x
FOR %%x in (Techsmith\*.snagacc) do %%x 

REM ---- Miscellanious Files
:misc
SET continue=y
echo.
echo.
echo.  Install Miscellanious Files
echo.
echo.
SET /P continue=Install? [%continue%]
if not x%continue%x==xyx GOTO phase2
echo.
echo.
echo. Installing Miscellanious Files
rem Signature
copy AuxiliaryFiles\notessign.html c:\
copy AuxiliaryFiles\*.cmd "c:\Utilities\*.cmd"
rem More of the miscelaneous stuff here if needed

REM ---- Stuff for the second phase. Programs that depend on other programs to be available
:phase2
for %%x in (phase2\*.*) do call installthis.cmd %%x

REM ---- Firefox Plug-ins
:firefox
SET continue=y
echo.
echo.
echo.  Install Firefox Plug-ins?
echo.
echo.
SET /P continue=Install? [%continue%]
if not x%continue%x==xyx GOTO end
echo.
echo.
echo. Installing Firefox plugins
plugins.html

:end
echo.
echo.
echo. So far so good, setting and stuff next!
echo.
echo.

installthis.cmd: it prompts for every file to be installed. If you find that unneccecary, you can alter the file easily.

@echo off
SET continue=y
echo.
echo.
echo.  Install %1 ?
echo.
echo.
SET /P continue=Install? [%continue%] 
if not x%continue%x==xyx GOTO notthis
echo.
echo.
echo. Installing %1
"%1"
:notthis