wissel.net

Since R6 we are able to manipulate replication formulas using Lotus Script. You simply retrieve the entry and update or delete it. There is only one problem: If you don't know what custom replication pairs are in your database you can't do anything about it. Since "wild" custom replication formulas are a nightmare to track down I created the following script and XSLT stylesheet to extract this information using DXL. My script simply creates documents that document the settings. It will be easy to extend the script to include deletion of the entries. Or you could modifiy it to track replication formulas in multiple databases.

As usual: your mileage might vary!

Option Public
Option Declare

Sub Initialize
	Dim db As NotesDatabase
	Dim notecol As NotesNoteCollection
	Dim exporter As NotesDXLExporter
	Dim importer As NotesDXLImporter
	Dim transformer As NotesXSLTransformer
	Dim result As String
	Dim stream As NotesStream
	
	Dim s As New NotesSession
	
	'Setup envionment
	Set db = s.CurrentDatabase
	
	'Create the collection
	Set notecol = db.CreateNoteCollection(False)
	Call notecol.SelectAllAdminNotes(True) 'ACL, Replication Formulas
	Call notecol.BuildCollection
	Print "Build the collection ..."
	
	'Get the transformation stylesheet
	Set stream = getRichTextSource("DocumentCustomReplicationFormulas")
	
	'Create the import/export/transformer
	Set exporter = s.CreateDXLExporter
	Set transformer = s.CreateXSLTransformer
	Set importer = s.CreateDXLImporter
	
	'Now we need to wire the exporter to the transformer to the importer
	Call exporter.SetInput(notecol)
	Call exporter.SetOutput(transformer)
	Call transformer.SetStylesheet(stream)
	Call transformer.setOutput(importer)
	Call importer.setOutput(db)
	
	'Set the parameters for processing
	exporter.ExitOnFirstFatalError = False
	importer.ReplaceDBProperties = False
	importer.ReplicaRequiredForReplaceOrUpdate = False
	importer.ACLImportOption = DXLIMPORTOPTION_IGNORE
	importer.DesignImportOption = DXLIMPORTOPTION_IGNORE
	importer.DocumentImportOption = DXLIMPORTOPTION_CREATE
	
	Print "Processing"
	On Error Resume Next
	
	Call exporter.Process
	Print "Backup completed"
	result = exporter.log
	Call stream.Close
	
	Beep	
	Msgbox result, 0, Cstr(importer.importednotecount) & " Documents created"
	
End Sub

Function getRichTextSource(SourceName As String) As NotesStream
	'Retrieves a RichTextitem from the XSLTDefinitions view
	Dim db As NotesDatabase
	Dim doc As NotesDocument
	Dim v As NotesView
	Dim tmpStream As NotesStream
	Dim rt As NotesRichTextItem
	
	Dim s As New NotesSession
	Set db = s.CurrentDatabase
	Set v = db.GetView("XSLTDefinitions")
	Set doc = v.GetDocumentByKey(SourceName,True)
	If doc Is Nothing Then
		Msgbox "XSLT Definition " & SourceName & "not found"
		Exit Function
	End If
	
	Set rt = doc.GetFirstItem("Body")
	Set tmpStream = s.CreateStream
	tmpStream.WriteText(rt.GetUnformattedText)
	tmpStream.Position = 0
	Set getRichTextSource = tmpStream
End Function